Если перед вами стоит задача быстро развернуть адресное хранение на работающей базе и при этом не парализовать работу сотрудников, используйте следующую пошаговую инструкцию.

Подготовка плацдарма

Первым делом требуется описать топологию будущего склада с ячейками. Садимся вместе с производственниками и кладовщиками, и на бумаге расчерчиваем будущий склад с ячейками: где у нас будут ряды, где стеллажи, сколько в них ярусов и полок.

• Ячейки с типом "Приемка" - это виртуальный или реальный пандус. Сюда товар падает в момент проведения Приходного ордера, и именно отсюда кладовщик будет забирать его для размещения в адресные ячейки.
• Ячейки с типом "Отгрузка": это ворота на выход со склада. Сюда товар перемещается из зоны хранения при сборке заказа, чтобы дожидаться передачи клиенту или погрузки в транспортное средство для перемещения.

Резюмируя, даже если в реальности у вас кладовщик принимает коробку и сразу ставит ее на полку, в 1С вам придется создать эти две служебные ячейки-зоны, иначе складские ордера просто не проведутся.

Графически данный процесс можно визуализировать с помощью блок-схемы ниже (реальный пример с проекта):

Как только топология склада будет ясна и понятна, требуется произвести вашему складу "пересадку мозга", т.е. объяснить самой 1С, что этот склад больше не работает по-старому, и произвести настройки ордерной схемы документооборота в системе в карточке вашего склада:

Заходим в карточку склада (вкладка "Ордерная схема и структура") и переключаем два судьбоносных параметра:

• Включаем ордерную схему документооборота (ставим галки "при поступлении" и "при отгрузке").

• В поле "Ячейки" выбираем значение "Использовать для хранения остатков номенклатуры".

И вот только после того, как карточка склада записана с этими настройками, система разрешает нам перейти к генерации топологии.

Генерация топологии склада

Вбивать сотни ячеек вручную - удел мазохистов, поэтому самый простой и надежный способ описать топологию склада в системе 1С:ERP - использовать встроенную обработку "Генерация топологии склада". Работает она быстро и просто, главное - правильно задать матрицу.

В подсистеме "Склад и доставка" в разделе "Сервис" ищем данную обработку и запускаем.

Здесь задается структура адресов (ряды, стеллажи, ярусы...), но ваша радость была бы не полной, если бы 1С не потребовала заполнить два важнейших аналитических реквизита: Типоразмер и Область хранения.

Как это должно работать в идеальном мире:

• Типоразмер ячейки: система должна знать точные физические габариты каждой полки (высота, ширина, глубина, грузоподъемность). Это нужно, чтобы умный алгоритм сам понимал, что, например, "этот материал на верхний ярус не влезет, а вот сюда встанут ровно две паллеты".
• Область хранения: Это логическое объединение ячеек с одинаковыми правилами. Например, отдельная зона для скоропортящихся товаров (в холодильники), отдельная зона для тяжелого негабарита (напольное хранение), отдельная для мелочевки и т.д.

Суровая реальность:

Если на старте задачи в ваши планы категорически не входит измерять рулеткой каждый стеллаж и взвешивать каждую коробку, да и время на реализацию ограничено, а вместо этого вам нужен быстрый и рабочий адресный склад, где люди просто знают, куда им идти за конкретным материалом, то тогдаединственным выходом является создание типоразмера "Без ограничения" (как видно на скриншоте), у которого не заданы габариты, а также создать всего одну универсальную область хранения на весь склад.

Данного "изящного" действия будет достаточно, чтобы ядро модуля адресного склада взлетело, и обработка сгенерировала вам полторы сотни (или сколько вам нужно?) ячеек с нужными настройками, позволив отложить сложные логистические расчеты весов и объемов до лучших времен (или навсегда), а кладовщики получат то, что им и нужно - понятные адреса ячеек без лишнего геморроя.

Хорошая новость заключается в том, что если вам в моменте потребуется расчертить ваш адресный склад на области хранения или описать типоразмеры ваших ячеек, то это без боли можно будет сделать позднее.

Упаковки преткновения

В обычной жизни бухгалтерии или менеджеров товар чаще всего измеряется, закупается и принимается в базовых единицах измерения: штуках, метрах, литрах, килограммах. Но когда мы включаем адресное хранение остатков, то у системы просыпается логистическое эго. Программа заявляет: "Я не могу положить абстрактную штуку на конкретную полку. Дайте мне физический объект! В чем лежит эта ваша штука? В коробке? На паллете? В пакете?"

Важная архитектурная особенность любого адресного склада:

• Товар обязан иметь заполненную упаковку в складском документе;
• Без упаковки 1С просто блокирует транзакцию, не позволяя ни положить товар в ячейку, ни забрать его оттуда.

Здесь требуется сделать стратегический выбор: либо заставить сотрудников склада замерять и заводить реальные коробки для тысяч старых позиций, либо использовать фиктивные упаковки.

Раз уж мы договорились на предыдущем шаге использовать безразмерные ячейки, то потребуются такие же фиктивные упаковки:

• Создаются универсальные наборы упаковок (например, один общий набор, где 1 штука равна 1 упаковке без указания точных габаритов и веса).
• Через обработку "Групповое измерение реквизитов" установить значение реквизита "Использовать упаковки" в старых карточках номенклатуры и привязать к ним этот универсальный набор.

Именно эта боль и стала главным катализатором для написания нашего скрипта. Мы поняли, что заставлять людей вручную прокликивать упаковки в каждой строке - это саботаж работы склада. Нам нужен был механизм, который делал бы это автоматически.

Более того, включать упаковки во всем справочнике номенклатуры - далеко не всегда целесообразно, ведь в системе может быть множество различных складов, в т.ч. не ордерных и без ячеек, где упаковки в номенклатурных карточках не нужны вовсе.

Для этого в документе "Приходный ордер на товары", ровно как и в документе "Расходный ордер на товары" была прикручена автоматизация в виде простой команды на форме, при нажатии на которую алгоритм пробегался по всей табличной части ордера, включал и заполнял внутри каждой номенклатурной позиции упаковки (если не было включено), и заполнял упаковку во всей табличной части документа. В итоге мы получили около идеальное решение: система автоматизирует данные только тогда и только для тех товаров, которые физически пересекают границу нашего адресного склада.

&НаКлиенте
Процедура ВключитьУпаковкиКоманда(Команда)
	
	Если Объект.Товары.Количество() = 0 Тогда
		Возврат; 
	КонецЕсли;
	
	Для Каждого СтрокаТЧ Из Объект.Товары Цикл
		Если СтрокаТЧ.Количество = 0 Тогда
			ПоказатьПредупреждение(Неопределено, "В таблице есть товары с незаполненным количеством!" + Символы.ПС + "Сначала укажите количество, а затем нажимайте кнопку.");
			Возврат; 
		КонецЕсли;
	КонецЦикла;	
	
	ВключитьУпаковкиНаСервере();
	
КонецПроцедуры

&НаСервере
Процедура ВключитьУпаковкиНаСервере()
	
	Если ЗначениеЗаполнено(Объект.Ссылка) Тогда
		ОрдерОбъект = Объект.Ссылка.ПолучитьОбъект();
	Иначе
		ОрдерОбъект = РеквизитФормыВЗначение("Объект");
	КонецЕсли;
	
	МассивОбработанных = Новый Массив; 
	
	Для Каждого СтрокаТЧ Из ОрдерОбъект.Товары Цикл
		СсылкаНоменклатура = СтрокаТЧ.Номенклатура;
		Если Не ЗначениеЗаполнено(СсылкаНоменклатура) ИЛИ СсылкаНоменклатура.ЭтоГруппа Тогда
			Продолжить;
		КонецЕсли;
		
		Если МассивОбработанных.Найти(СсылкаНоменклатура) <> Неопределено Тогда
			Продолжить;
		КонецЕсли;
		МассивОбработанных.Добавить(СсылкаНоменклатура);
		
		ИмяЕдиницы = СокрЛП(СсылкаНоменклатура.ЕдиницаИзмерения.Наименование);
		НаборДляЗаписи = Справочники.НаборыУпаковок.НайтиПоНаименованию(ИмяЕдиницы);
		
		Если Не ЗначениеЗаполнено(НаборДляЗаписи) Тогда
			Продолжить;
		КонецЕсли;
		
		Если СсылкаНоменклатура.ИспользоватьУпаковки = Ложь ИЛИ СсылкаНоменклатура.НаборУпаковок <> НаборДляЗаписи Тогда
			ОбъектНом = СсылкаНоменклатура.ПолучитьОбъект();
			ОбъектНом.ИспользоватьУпаковки = Истина;
			ОбъектНом.НаборУпаковок = НаборДляЗаписи;
			ОбъектНом.ОбменДанными.Загрузка = Истина;
			Попытка ОбъектНом.Записать(); Исключение КонецПопытки;
		КонецЕсли;
	КонецЦикла;
	
	МассивНаборов = Новый Массив;
	Для Каждого СтрокаТЧ Из ОрдерОбъект.Товары Цикл
		Набор = СтрокаТЧ.Номенклатура.НаборУпаковок;
		Если ЗначениеЗаполнено(Набор) И МассивНаборов.Найти(Набор) = Неопределено Тогда
			МассивНаборов.Добавить(Набор);
		КонецЕсли;
	КонецЦикла;
	
	Если МассивНаборов.Количество() > 0 Тогда
		Запрос = Новый Запрос;
		Запрос.Текст = 
			"ВЫБРАТЬ
			|	УпаковкиЕдиницыИзмерения.Владелец КАК Набор,
			|	УпаковкиЕдиницыИзмерения.Наименование КАК НаименованиеУпаковки,
			|	МИНИМУМ(УпаковкиЕдиницыИзмерения.Ссылка) КАК Упаковка
			|ИЗ
			|	Справочник.УпаковкиЕдиницыИзмерения КАК УпаковкиЕдиницыИзмерения
			|ГДЕ
			|	УпаковкиЕдиницыИзмерения.Владелец В(&МассивНаборов)
			|	И УпаковкиЕдиницыИзмерения.ПометкаУдаления = ЛОЖЬ
			|СГРУППИРОВАТЬ ПО
			|	УпаковкиЕдиницыИзмерения.Владелец,
			|	УпаковкиЕдиницыИзмерения.Наименование";
			
		Запрос.УстановитьПараметр("МассивНаборов", МассивНаборов);
		ТаблицаУпаковок = Запрос.Выполнить().Выгрузить();
		
		Для Каждого СтрокаТЧ Из ОрдерОбъект.Товары Цикл
			Если Не ЗначениеЗаполнено(СтрокаТЧ.Упаковка) И ЗначениеЗаполнено(СтрокаТЧ.Номенклатура.НаборУпаковок) Тогда
				ПараметрыПоиска = Новый Структура("Набор, НаименованиеУпаковки", СтрокаТЧ.Номенклатура.НаборУпаковок, СтрокаТЧ.Номенклатура.ЕдиницаИзмерения.Наименование);
				НайденныеСтроки = ТаблицаУпаковок.НайтиСтроки(ПараметрыПоиска);
				
				Если НайденныеСтроки.Количество() > 0 И ЗначениеЗаполнено(НайденныеСтроки[0].Упаковка) Тогда
					СтрокаТЧ.Упаковка = НайденныеСтроки[0].Упаковка;
					Попытка СтрокаТЧ.КоличествоУпаковок = СтрокаТЧ.Количество; Исключение КонецПопытки;
				КонецЕсли;
			КонецЕсли;
		КонецЦикла;
	КонецЕсли;
	
	ОрдерОбъект.ОбменДанными.Загрузка = Истина; 
	ОрдерОбъект.Записать(РежимЗаписиДокумента.Запись);
	
	ЗначениеВРеквизитФормы(ОрдерОбъект, "Объект");
	
КонецПроцедуры

Ввод остатков на рабочей базе несколько лет спустя

Реализовать адресное хранение остатков на новой, чистой и девственной базе - задача несложная. Но если ваша организация успешно работает в ERP/УТ/КА уже несколько лет и ведет складской учет, то все становится значительно сложнее - просто включить адресное хранение и откинуться на спинку кресла нельзя, ведь весь учтенный на складе товар отсутствует в складских регистрах системы адресного хранения.

На данном этапе требуется зафиксировать точку старта работы по новой логике, и для этого в системе 1С:ERP есть специальный документ "Ввод начальных остатков товаров после перехода на адресную систему хранения".

Идея простая: выгрузить текущие остатки организации в этот документ, указать для них дефолтную ячейку (например, "Зону приемки", чтобы склад хотя бы начал видеть товар на балансе), нажать кнопку "Провести" и пойти пить кофе, однако при попытке проведения документ, скорее всего, выплюнет вам простыню ошибок - 1С наотрез отказывается распределять товар по ячейкам.

Причина всё та же: упаковки. Поскольку ваша база велась несколько лет без адресной системы хранения, у 99% старых номенклатурных карточек использование упаковок было отключено. А адресный склад, как мы уже поняли, не умеет работать с базовыми единицами хранения - ему требуются упаковки.

Вышеописанный алгоритм (тот самый, что мы использовали в ордерах) исправления упаковок необходимо масштабировать и применить (например, через внешнюю обработку) к табличной части ввода остатков перед его проведением. Это позволит "приземлить" всю многолетнюю историю остатков склада в WMS за пару секунд.

Финансы против адресного хранения - как мы потрепали нервы бухгалтерии ордерным складом, но потом извинились.

Учитывая тот факт, что до включения адресного хранения ваша компания жила несколько лет, и отгрузка товара со склада организации проводилась буквально одной кнопкой - "Провести и закрыть", то после включения данный бизнес-процесс значительно усложняется.

Мы поняли: если не вернуть людям их любимую одну кнопку, проект автоматизации просто саботируют. Нам нужно было извиниться перед юзерами единственным понятным для них способом - дать им инструмент автоматизации, который сделает всю цепочку за них. По одной кнопке. Прямо из ордера.

В Приходном ордере (Приемка): бухгалтер или кладовщик просто нажимает кнопку. Скрипт проверяет карточки номенклатуры, включает упаковки (о чем мы писалии чуть выше), а затем автоматически создает Задание на размещение. Программа сама берет товар из транзитной "Зоны приемки" и перемещает его в выбранную пару мгновениями ранее в диалоговом окне ячейку. Ордер сам переключается в статус "Принят". Для пользователя это заняло две секунды и один клик.

&НаСервере
Процедура СформироватьРазмещениеНаСервере(ЦелеваяЯчейкаРазмещения)
	
	ОрдерОбъект = РеквизитФормыВЗначение("Объект");
	
	ЯчейкаПриемкиФакт = ОрдерОбъект.ЗонаПриемки;
	Если Не ЗначениеЗаполнено(ЯчейкаПриемкиФакт) Тогда
		ВызватьИсключение "В Приходном ордере не заполнена ""Зона приемки""!";
	КонецЕсли;
	
	Если Не ЗначениеЗаполнено(ЦелеваяЯчейкаРазмещения) Тогда
		ВызватьИсключение "Не выбрана целевая ячейка для размещения товаров!";
	КонецЕсли;
	
	ЗаданиеОбъект = Документы.ОтборРазмещениеТоваров.СоздатьДокумент(); 
	ЗаданиеОбъект.ВидОперации = Перечисления.ВидыОперацийОтбораРазмещенияТоваров.Размещение; 
	ЗаданиеОбъект.Склад       = ОрдерОбъект.Склад;
	ЗаданиеОбъект.Дата        = ОрдерОбъект.Дата; 
	ЗаданиеОбъект.ЗонаПриемки = ЯчейкаПриемкиФакт; 
	
	ЗаданиеОбъект.Комментарий = "Создано автоматически на основании документа: Приходный ордер на товары " 
								+ ОрдерОбъект.Номер + " от " + Формат(ОрдерОбъект.Дата, "ДЛФ=D"); 
								
	Для Каждого СтрОрдера Из ОрдерОбъект.Товары Цикл
		
		СтрОтбор = ЗаданиеОбъект.ТоварыОтбор.Добавить();
		СтрОтбор.Номенклатура     = СтрОрдера.Номенклатура;
		СтрОтбор.Характеристика   = СтрОрдера.Характеристика;
		СтрОтбор.Серия            = СтрОрдера.Серия;
		СтрОтбор.Назначение       = СтрОрдера.Назначение;
		СтрОтбор.Упаковка         = СтрОрдера.Упаковка;
		СтрОтбор.Ячейка           = ЯчейкаПриемкиФакт; 
		СтрОтбор.Количество       = СтрОрдера.Количество;
		СтрОтбор.КоличествоУпаковок = СтрОрдера.КоличествоУпаковок;
		СтрОтбор.КоличествоОтобрано = СтрОрдера.Количество;
		СтрОтбор.КоличествоУпаковокОтобрано = СтрОрдера.КоличествоУпаковок;
		
		СтрРазмещение = ЗаданиеОбъект.ТоварыРазмещение.Добавить();
		СтрРазмещение.Номенклатура     = СтрОрдера.Номенклатура;
		СтрРазмещение.Характеристика   = СтрОрдера.Характеристика;
		СтрРазмещение.Серия            = СтрОрдера.Серия;
		СтрРазмещение.Назначение       = СтрОрдера.Назначение;
		СтрРазмещение.Упаковка         = СтрОрдера.Упаковка;
		СтрРазмещение.Ячейка           = ЦелеваяЯчейкаРазмещения; 
		СтрРазмещение.Количество       = СтрОрдера.Количество;
		СтрРазмещение.КоличествоУпаковок = СтрОрдера.КоличествоУпаковок;
		СтрРазмещение.КоличествоРазмещено = СтрОрдера.Количество;
		СтрРазмещение.КоличествоУпаковокРазмещено = СтрОрдера.КоличествоУпаковок;
		
	КонецЦикла;
	
	ЗаданиеОбъект.Статус = Перечисления.СтатусыОтборовРазмещенийТоваров.ВыполненоБезОшибок;
	
	Попытка
		ЗаданиеОбъект.Записать(РежимЗаписиДокумента.Проведение);
	Исключение
		ВызватьИсключение "Ошибка при проведении Задания на размещение! Ошибка: " + ОписаниеОшибки();
	КонецПопытки;
	
	ОрдерДляЗакрытия = ОрдерОбъект.Ссылка.ПолучитьОбъект();
	ОрдерДляЗакрытия.Статус = Перечисления.СтатусыПриходныхОрдеров.Принят;
	
	ОрдерДляЗакрытия.Комментарий = "Автоматически сформировано складское задание на размещение № " + ЗаданиеОбъект.Номер;
	
	Попытка
		ОрдерДляЗакрытия.Записать(РежимЗаписиДокумента.Проведение);
	Исключение
		ВызватьИсключение "Ошибка при финальном проведении Приходного ордера! Ошибка: " + ОписаниеОшибки();
	КонецПопытки;
	
	ЗначениеВРеквизитФормы(ОрдерДляЗакрытия, "Объект");
	
КонецПроцедуры

В Расходном ордере (Отгрузка): тут мы написали свой собственный мини-WMS движок. По нажатию кнопки система делает прямой запрос к регистру ТоварыВЯчейках, анализирует остатки на складе (исключая транзитные зоны отгрузки и приемки), распределяет списываемое количество по ячейкам хранения по убыванию остатка, сама создает документ "Отбор размещение товаров" со статусом "Выполнено без ошибок" и переводит ордер в статус "Отгружен".

&НаСервере
Процедура СформироватьОтборНаСервере()
    
    ОрдерОбъект = РеквизитФормыВЗначение("Объект");
    ЯчейкаОтгрузкиФакт = ОрдерОбъект.ЗонаОтгрузки;
    
    Если Не ЗначениеЗаполнено(ЯчейкаОтгрузкиФакт) Тогда
        ВызватьИсключение "В Расходном ордере не заполнена «Зона отгрузки»! Заполните её перед отгрузкой.";
    КонецЕсли;
    
    Если ОрдерОбъект.Статус = Перечисления.СтатусыРасходныхОрдеров.Подготовлен Тогда
        ОрдерОбъект.Статус = Перечисления.СтатусыРасходныхОрдеров.КОтбору;
        ОрдерОбъект.Записать(РежимЗаписиДокумента.Проведение);
    КонецЕсли;
    
    ЗаданиеОбъект = Документы.ОтборРазмещениеТоваров.СоздатьДокумент();
    ЗаданиеОбъект.ВидОперации 			  = Перечисления.ВидыОперацийОтбораРазмещенияТоваров.Отбор; 
    ЗаданиеОбъект.Склад       			  = ОрдерОбъект.Склад;
    ЗаданиеОбъект.ЗонаОтгрузки 			  = ЯчейкаОтгрузкиФакт; 
    ЗаданиеОбъект.Распоряжение 			  = ОрдерОбъект.Ссылка;
    ЗаданиеОбъект.Дата        			  = ОрдерОбъект.Дата;
	ЗаданиеОбъект.Исполнитель			  = ПользователиСлужебный.АвторизованныйПользователь();
	ЗаданиеОбъект.Ответственный 		  = ПользователиСлужебный.АвторизованныйПользователь();
	ЗаданиеОбъект.ДатаНачалаВыполнения    = ОрдерОбъект.Дата;
	ЗаданиеОбъект.ДатаОкончанияВыполнения = ОрдерОбъект.Дата;
	
    МассивНоменклатуры = ОрдерОбъект.ОтгружаемыеТовары.ВыгрузитьКолонку("Номенклатура");
    
    ЗапросОстатков = Новый Запрос;
    ЗапросОстатков.Текст = 
        "ВЫБРАТЬ
        |    ТоварыВЯчейках.Номенклатура,
        |    ТоварыВЯчейках.Характеристика,
        |    ТоварыВЯчейках.Назначение,
        |    ТоварыВЯчейках.Серия,
        |    ТоварыВЯчейках.Ячейка,
        |    ТоварыВЯчейках.ВНаличииОстаток КАК ОстатокВЯчейке
        |ИЗ
        |    РегистрНакопления.ТоварыВЯчейках.Остатки(
        |        ,
        |        Ячейка.Владелец = &Склад 
        |        И Номенклатура В (&МассивНоменклатуры)
        |        И Ячейка.ТипСкладскойЯчейки <> ЗНАЧЕНИЕ(Перечисление.ТипыСкладскихЯчеек.Приемка)
        |        И Ячейка.ТипСкладскойЯчейки <> ЗНАЧЕНИЕ(Перечисление.ТипыСкладскихЯчеек.Отгрузка)
        |    ) КАК ТоварыВЯчейках
        |ГДЕ
        |    ТоварыВЯчейках.ВНаличииОстаток > 0
        |УПОРЯДОЧИТЬ ПО
        |    ОстатокВЯчейке УБЫВ";
        
    ЗапросОстатков.УстановитьПараметр("Склад", ОрдерОбъект.Склад);
    ЗапросОстатков.УстановитьПараметр("МассивНоменклатуры", МассивНоменклатуры);
    ТаблицаЯчеек = ЗапросОстатков.Выполнить().Выгрузить();
    
    ТекстОшибкиНехватки = ""; 
    
    Для Каждого СтрОрдера Из ОрдерОбъект.ОтгружаемыеТовары Цикл
        ОсталосьСобрать = СтрОрдера.Количество;
        
        ПараметрыОтбораСтрок = Новый Структура;
        ПараметрыОтбораСтрок.Вставить("Номенклатура", СтрОрдера.Номенклатура);
        ПараметрыОтбораСтрок.Вставить("Назначение",   СтрОрдера.Назначение);
        
        СтрокиСТоваром = ТаблицаЯчеек.НайтиСтроки(ПараметрыОтбораСтрок);
        
        Для Каждого СтрЯчейки Из СтрокиСТоваром Цикл
            Если ОсталосьСобрать <= 0 Тогда Прервать; КонецЕсли;
            Если СтрЯчейки.ОстатокВЯчейке <= 0 Тогда Продолжить; КонецЕсли;
            
            БеремИзЯчейки = Мин(ОсталосьСобрать, СтрЯчейки.ОстатокВЯчейке);
            
            Если СтрОрдера.Количество = 0 Тогда БеремУпаковок = 0;
            Иначе БеремУпаковок = (БеремИзЯчейки / СтрОрдера.Количество) * СтрОрдера.КоличествоУпаковок; КонецЕсли;
            
            СтрОтбор = ЗаданиеОбъект.ТоварыОтбор.Добавить();
            ЗаполнитьЗначенияСвойств(СтрОтбор, СтрОрдера);
            СтрОтбор.Ячейка = СтрЯчейки.Ячейка; 
            СтрОтбор.Количество = БеремИзЯчейки;
            СтрОтбор.КоличествоУпаковок = БеремУпаковок; 
            СтрОтбор.КоличествоОтобрано = БеремИзЯчейки;
            СтрОтбор.КоличествоУпаковокОтобрано = БеремУпаковок;
            
            СтрРазмещение = ЗаданиеОбъект.ТоварыРазмещение.Добавить();
            ЗаполнитьЗначенияСвойств(СтрРазмещение, СтрОрдера);
            СтрРазмещение.Ячейка = ЯчейкаОтгрузкиФакт; 
            СтрРазмещение.Количество = БеремИзЯчейки;
            СтрРазмещение.КоличествоУпаковок = БеремУпаковок;
            СтрРазмещение.КоличествоРазмещено = БеремИзЯчейки;
            СтрРазмещение.КоличествоУпаковокРазмещено = БеремУпаковок;
            
            ОсталосьСобрать = ОсталосьСобрать - БеремИзЯчейки;
            СтрЯчейки.ОстатокВЯчейке = СтрЯчейки.ОстатокВЯчейке - БеремИзЯчейки;
        КонецЦикла;
        
        Если ОсталосьСобрать > 0 Тогда
            ТекстОшибкиНехватки = ТекстОшибкиНехватки + Символы.ПС + "— " + СтрОрдера.Номенклатура + " (не хватает: " + ОсталосьСобрать + ")";
        КонецЕсли;
    КонецЦикла;
    
    Если ЗначениеЗаполнено(ТекстОшибкиНехватки) Тогда
        ВызватьИсключение "Следующие товары не найдены в ячейках хранения (возможно, они еще лежат в Зоне приемки):" 
            + ТекстОшибкиНехватки + Символы.ПС + Символы.ПС 
            + "Сначала выполните размещение этих товаров на стеллажи!";
    КонецЕсли;
    
    ЗаданиеОбъект.Статус = Перечисления.СтатусыОтборовРазмещенийТоваров.ВыполненоБезОшибок; 
    ЗаданиеОбъект.Записать(РежимЗаписиДокумента.Проведение);
    
    Для Каждого СтрОрдера Из ОрдерОбъект.ОтгружаемыеТовары Цикл
        СтрОрдера.Действие = Перечисления.ДействияСоСтрокамиОрдеровНаОтгрузку.Отгрузить; 
    КонецЦикла;
    
    ОрдерОбъект.Статус = Перечисления.СтатусыРасходныхОрдеров.Отгружен; 
    ОрдерОбъект.Записать(РежимЗаписиДокумента.Проведение);
    
    ЗначениеВРеквизитФормы(ОрдерОбъект, "Объект");

КонецПроцедуры

При разработке автоматизации важно учитывать, что типовой механизм 1С:ERP по умолчанию работает через консолидацию отгрузок - система пытается объединить множество расходных ордеров под общие распоряжения, чтобы выдать кладовщику одно сводное задание на сборку товаров для целого рейса или зоны.

Краткие итоги:

Следуя этой методике, вы сможете развернуть полноценный WMS-контур, не ломая привычные бизнес-процессы компании.

• Склад перейдет на адресное хранение без остановки отгрузок ни на один день;
• Бухгалтерия и менеджеры сохранят бизнес-процесс в один клик и не будут саботировать учет;
• Кладовщики увидят в отчетах четкие адреса полок и остатки вместо интуитивного поиска товаров.

Да, такой подход частично обходит канонические механизмы консолидации заданий по ролям и использует "костыли" в виде безразмерных ячеек и фиктивных упаковок. Но помните: автоматизация пишется для людей и непрерывности бизнеса. Иногда, чтобы система реально заработала, архитектору нужно проявить инженерную наглость и упростить избыточную логику платформы.

Для подключения печатной формы не нужно вносить изменений в типовую конфигурацию.
Для подключения требуется выполнить следующие шаги:

• Открыть меню "НСИ и администрирование" - "Печатные формы и обработки"- "Дополнительные отчеты и обработки"
• Нажать на кнопку "Создать", выбрать файл обработки. Все необходимые поля заполнятся автоматически
• Нажать "Записать и закрыть"
• После этого, в документе "Реализация услуг и прочих активов" в меню "Печать" появится пункт "Справка-расчет Рублевые суммы документа в валюте (РУиПА)"

Скачать: https://disk.yandex.ru/d/ancWKxf3RgGtsA

Взято с сайта ИТС.

• АА - префикс организации (если в информационной базе ведется учет по нескольким организациям, то у каждой организации может быть свой префикс);
  ББ - префикс информационной базы;
• ВВ - дополнительный префикс, который может быть назначен администратором;
• 000001 - номер объекта в информационной базе

Как правило, нумерация сквозная, и является уникальной в пределах одного года. Более тонкую настройку нумерации (периодичности) можно изменить в конфигураторе в свойствах самого объекта метаданных на вкладке "Нумерация":

По умолчанию, дополнительный пользовательский префикс не формируется, и для его изменения есть два основных способа, которые мы рассмотрим ниже.

Изменение префикса организации

Префикс организации задается непосредственно в карточке организации, вне зависимости от используемой конфигурации:

Рекомендуем устанавливать префикс таким образом, чтобы из этих двух символов было понятно, о какой организации идёт речь. Например:

1. "Ёлочный базар ООО" - ЁБ
2. "Железо Оптом ООО" - ЖО
3. "Хромированные утюги ООО " - ХУ

После изменения префикса организации, нумерация документов будет выглядеть следующим образом:

Изменение префикса информационной базы

Обычно третий и четвёртый символ заполняют при настройке синхронизации баз - это удобно, ведь документы, пришедшие из другой информационной базы, визуально не смешиваются, т.к. имеют другой индекс ИБ.

Заходим в настройку синхронизации информационных (раздел "НСИ и администрирование") баз и можем поменять префикс:

Если префикс информационной базы не указан, то используется префикс по умолчанию "00" (ноль-ноль).

Рекомендации по префиксу информационной базы такие:

• УТ - для конфигурации "1С: Управление торговлей";
• БП - для конфигурации "1С: Бухгалтерия предприятия";
• ЗК - для конфигурации "1С: Зарплата и управление персоналом";
• УП - для конфигурации "1С: ERP Управление производственным предприятием";
• КА - для конфигурации "1С: Комплексная автоматизация";
• ДО - для конфигурации "1С: Документооборот"

Изменение пользовательского префикса

Довольно часто спрашивают, а как, собственно, установить пользовательский префикс у документов, которые не имеют настройки префикса?

На самом деле, очень просто.

Если конфигурация позволяет произвести настройку префикса, то рекомендую делать это именно в настройках программы. Например, в 1С: КА, 1С: ERP и 1С: УТ можно установить префиксы у счет-фактур:

Но чаще всего данной манипуляции бывает недостаточно, и если, допустим, вы хотите у документа "Счет-фактура налогового агента" установить префикс "НУ", чтобы документ имел номер, например, ТДКА-НУ00001, то такой настройки в системе нет. Но делается это достаточно просто.

Откроем нашу базу в режиме "Конфигуратор" и в дереве объектов метаданных найдём тот документ, которому мы решили присвоить новый префикс в системе, и сразу переходим в модуль объекта:

В модуле объекта документа находим процедуру-обработчик "ПриУстановкеНовогоНомера", щелкаем по наименованию процедуры правой кнопкой мыши и выбираем "Добавить в расширение" -> тип вызова "Вызывать вместо (с контролем)". Экранируем строчку со старым префиксом, используя вставки #Удаление, #КонецУдаления, и добавляем свою строчку с помощью #Вставка и #КонецВставки (см. рисунок ниже)

Используя данные вставки (удаления) мы как бы "удаляем" старый код, а вставками ниже (вставка/конец вставки) мы добавляем свой код, который и отрабатывает в конечном итоге. В данном конкретном примере я указал в качестве префикса Счет-фактуры налогового агента "НУ".

Таким образом, мы оставляем нашу конфигурацию на поддержке, аккуратно скорректировав поведение префиксации с помощью механизма расширений. Данный способ не подойдёт для информационных баз, размещенных в облачном сервисе "Фреш" и ему подобных.

Если было полезно - безумно рад, делитесь данной информацией с коллегами.

Если вам потребуется помощь - пишите.

Необходимо создать документ «Операция», с помощью которого пользователь должен иметь возможность вести проводки с произвольной корреспонденцией счетов. При решении задачи следует учитывать возможность наличия проводок, сформированных с помощью данного документа.

Требуется реализовать возможность ведения учета товаров в разрезе мест хранения и партий товаров. Под партией товара понимается документ, регистрирующий его (товара) поступление.

В документе «Приходная накладная» склад указывается в табличной части для каждой строки и формируются следующие проводки:

Дт «Товары» - Кт «Поставщики» на количество и сумму закупаемого товара.

Продажа товара производится со склада и регистрируется документом «Расходная накладная», cклад указывается в реквизите самого документа. При заполнении документа партия товара не указывается. При проведении производится проверка достаточности количества на указанном складе продаваемого товара.

Документ «Расходная накладная» реализует следующие проводки:

Дт «Прибыли и убытки» - Кт «Товары» на количество и сумму себестоимости;

Дт «Покупатели» - Кт «Прибыли и убытки» на сумму в продажных ценах.

При продаже товара списание партий этого товара производится либо по дисциплине LIFO («последним пришел, первым ушел»), либо FIFO («первым пришел, первым ушел»). Какая из дисциплин будет использоваться, определяется в начале года и в течение года не меняется.

Себестоимость товара рассчитывается в разрезе партий на складе для данного товара.

Используя план видов характеристик необходимо предоставить возможность пользователю добавить произвольное количество дополнительных характеристик к каждому товару (материал, цвет, страна-производитель и т.д.)

Необходимо построить отчет о продажах товаров. Дополнительно данные в отчете должны быть сгруппированы по выбранной характеристике.

Продажи товаров за период с 01.01.2014 по 31.01.2014

Решение:

Для начала, требуется создать и настроить в каркасной конфигурации регистр бухгалтерии "Управленческий".

Создаем новый документ «Операция». У него не будет ни реквизитов, ни табличных частей. На закладке Движения запрещаем проведение документа и указываем, что документ является регистратором для регистра бухгалтерии «Управленческий».

Создаем форму документа «Операция».

В редакторе формы на закладке Реквизиты из коллекции Движения перетаскиваем набор записей регистра бухгалтерии «Управленческий» на закладку Элементы. При появлении вопроса «Добавить колонки...» отвечаем «Да».

Важный момент: так как колонки автоматически добавляются в соответствии со структурой регистра бухгалтерии, то нужно сначала выполнить настройку регистра бухгалтерии и только после этого создавать документ «Операция», т.к. в противном случае окажется, что на форме будет не хватать колонок для ввода данных.

Например, если сначала создать документ «Операция», а потом в регистре бухгалтерии добавить измерение «Организация», то в документе «Операция» организацию указать не будет возможности. Нужно будет вернуться в форму документа «Операция» и доработать ее.

По кнопке "Записать" проводки запишутся в регистр бухгалтерии. Убедимся в этом, открыв форму списка регистра бухгалтерии "Управленческий".

Документ «Операция» готов, и для сдачи экзамена больше ничего и не требуется. Однако, в реальной жизни пользоваться таким документом не очень удобно, и есть смысл произвести еще парочку простых, но очень полезных доработок.

Как правило, период (дата) в проводке всегда совпадает с датой документа-регистратора, поэтому имеет смысл реализовать алгоритм в модуле объекта документа "Операция", который будет заполнять эти данные автоматически. В обработчик события "ПередЗаписью" добавим следующий код:

Процедура ПередЗаписью(Отказ, РежимЗаписи, РежимПроведения)
    Для Каждого Проводка Из Движения.Управленческий Цикл
        Проводка.Период = Дата;
    КонецЦикла;
КонецПроцедуры

Особенности документа "Операция":

Если вам требуется отменить участие документа "Операция" в учете, то установка пометки удаления не отменяет его проводки. Можете убедиться в этом сами - поставьте пометку удаления у созданного вами документа и проверьте, что по регистру бухгалтерии "Управленческий" проводки остались на месте.

Для решения данной задачи можно воспользоваться свойством записи регистра бухгалтерии Активность. Записи со снятой активностью физически остаются в таблице движений регистра бухгалтерии, но в таблицы итогов регистра бухгалтерии такие записи не включаются. Соответственно, отключив активность движений документа, исключим его влияние на состояние учета.

Реализуем синхронизацию пометки удаления документа «Операция» и значений активности движений документа. При установке пометки удаления будем отключать активность движений, при снятии пометки удаления будем включать активность движений. Автоматическое заполнение периода в движениях также будем выполнять:

Для этого в модуле объекта документа «Операция» добавим программный код:

Процедура ПередЗаписью(Отказ, РежимЗаписи, РежимПроведения)
    
    Активность = Не ПометкаУдаления;    
    
    Проводки = Движения.Управленческий;
       
    Если  Не Проводки.Записывать Тогда
        Проводки.Прочитать();
    КонецЕсли;
    
    НужноЗаписывать = Проводки.Записывать;
    
    Для Каждого Проводка Из Проводки Цикл
        
        Если Проводка.Период <> Дата Тогда
            Проводка.Период = Дата;
            НужноЗаписывать = Истина;
        КонецЕсли;
        
        Если Проводка.Активность <> Активность Тогда
            Проводка.Активность = Активность;
            НужноЗаписывать = Истина;
        КонецЕсли;
        
    КонецЦикла;
    
    Проводки.Записывать = НужноЗаписывать;  

КонецПроцедуры

Код требуется разместить именно в модуле объекта, чтобы данный алгоритм корректно отрабатывал даже при работе из списка документов, т.е. даже если документ не открыт пользователем.

Приходная накладная:

Ничего умнее не придумал.